CreatePopupMenu()

Syntax

Ergebnis = CreatePopupMenu(#Menü)

Erstellt ein neues leeres Popup-Menü.

Parameter

#Menü

Die Nummer, mit der das neue Menü identifiziert wird. #PB_Any kann verwendet werden, um diese Nummer automatisch zu generieren.

Rückgabewert

Ein Wert ungleich Null, wenn das Menü erfolgreich erstellt wurde, andernfalls Null. Wenn #PB_Any als #Menü Parameter verwendet wurde, dann wird bei Erfolg die generierte Nummer zurückgegeben.

Anmerkungen

Um ein Popup-Menü mit Unterstützung für Bilder zu erstellen, verwenden Sie CreatePopupImageMenu().

Unmittelbar nach dem Erstellen des Menüs wird dieses das aktuelle Menü zum Einfügen weiterer Einträge. Es ist nun möglich, Funktionen wie z.B. MenuTitle(), MenuItem(), MenuBar(), OpenSubMenu() zum weiteren Aufbau des Menüs zu verwenden.

DisplayPopupMenu() kann benutzt werden, um dieses Popup-Menü an einer beliebigen Position auf dem Bildschirm darzustellen.

Um alle Menü-Ereignisse korrekt zu handhaben, siehe die Beschreibung der folgenden Befehle:
WaitWindowEvent() (alternativ WindowEvent())
EventWindow()
EventMenu()

Beispiel

  If OpenWindow(0, 200, 200, 200, 120, "Popup-Menu Example")
  
    If CreatePopupMenu(0)      ; hier beginnt das Erstellen des Popup-Menüs...
      MenuItem(1, "Open")      ; Sie können alle Befehle zum Erstellen eines Menüs
      MenuItem(2, "Save")      ; verwenden, ganz wie bei einem normalen Menü...
      MenuItem(3, "Save as")
      MenuItem(4, "Quit")
      MenuBar()
      OpenSubMenu("Recent files")
        MenuItem(5, "PureBasic.exe")
        MenuItem(6, "Test.txt")
      CloseSubMenu()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()    ; überprüfe Window-Ereignisse
      
      Select Event
        Case #PB_Event_RightClick       ; rechte Maustaste wurde gedrückt =>
          DisplayPopupMenu(0, WindowID(0))  ; zeige jetzt das Popup-Menü an
          
        Case #PB_Event_Menu        ; ein Eintrag des Popup-Menüs wurde angeklickt
          Select EventMenu()       ; ermittle den angeklickten Menü-Eintrag...
            Case 1 : Debug "Menu: Open"
            Case 2 : Debug "Menu: Save"
            Case 3 : Debug "Menu: Save as"
            Case 4 : End
            Case 5 : Debug "Menu: PureBasic.exe"
            Case 6 : Debug "Menu: Text.txt"
          EndSelect
          
      EndSelect
      
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

CreatePopupImageMenu(), DisplayPopupMenu(), CreateMenu(), CreateImageMenu(), FreeMenu(), MenuTitle(), MenuItem(), MenuBar(), OpenSubMenu()

Unterstützte OS

Alle