MessageRequester()

Syntax

Ergebnis = MessageRequester(Titel$, Text$, [, Flags])

Öffnet einen ('blocking') Requester zum Anzeigen einiger Informationen. Die Programmausführung wird vollständig angehalten, bis der Benutzer den Requester schließt.

Wird der optionale 'Flag' Parameter nicht angegeben, erhalten Sie den Standard-Requester mit 'Ok' Schalter. Als optionalen 'Flag' Parameter können Sie einen der folgenden angeben:

  #PB_MessageRequester_YesNo       : Um die 'Yes' (Ja) oder 'No' (Nein) Schalter zu erhalten
  #PB_MessageRequester_YesNoCancel : Um die 'Yes' (Ja), 'No' (Nein) und 'Cancel' (Abbruch) Schalter zu erhalten
  #PB_MessageRequester_Ok          : Um nur einen 'Ok' Schalter zu erhalten 

Mögliche Rückgabewerte sind folgende Konstanten:

  #PB_MessageRequester_Yes    : es wurde der 'Yes' (Ja) Schalter gedrückt
  #PB_MessageRequester_No     : es wurde der 'No' (Nein) Schalter gedrückt
  #PB_MessageRequester_Cancel : es wurde der 'Cancel' (Abbruch) Schalter gedrückt

Beispiel:

  ; Einfacher MessageRequester  (normalerweise nur zur Informationsausgabe benutzt)
  ; (Ergebnis ist immer dasselbe, deshalb überprüfen wir es hier nicht)
  MessageRequester("Information", "Nur ein kurzer Informationstext.", #PB_MessageRequester_Ok)

  ; MessageRequester mit Ja / Nein Schaltern  (normalerweise für Fragen benutzt)
  ; (Ergebnis wird im folgenden Informations-Requester angezeigt.)
  Result = MessageRequester("Titel", "Bitte machen Sie Ihre Eingabe:", #PB_MessageRequester_YesNo)
  a$ = "Das Ergebnis des vorherigen Requesters war: "
  If Result = #PB_MessageRequester_Yes       ; Ja-Schalter wurde gedrückt
    a$ + "Ja"
  Else                                       ; Nein-Schalter wurde gedrückt
    a$ + "Nein"
  EndIf
  MessageRequester("Information", a$, #PB_MessageRequester_Ok)

  ; MessageRequester mit Ja / Nein / Abbrechen Schaltern (normalerweise für Fragen benutzt)
  ; (Ergebnis wird im folgenden Informations-Requester angezeigt.)
  Result = MessageRequester("Titel", "Bitte machen Sie Ihre Eingabe:", #PB_MessageRequester_YesNoCancel) 
  a$ = "Das Ergebnis des vorherigen Requesters war: "
  If Result = #PB_MessageRequester_Yes       ; Ja-Schalter wurde gedrückt
    a$ + "Ja"
  ElseIf Result = #PB_MessageRequester_No    ; Nein-Schalter wurde gedrückt
    a$ + "Nein"
  Else                                       ; Abbrechen-Schalter oder Esc wurde gedrückt
    a$ + "Abbrechen"
  EndIf
  MessageRequester("Information", a$, #PB_MessageRequester_Ok)

Hinweis: In PureBasic werden auch viele weitere Konstanten der Windows API unterstützt. Diese sind dann allerdings nicht plattformübergreifend kompatibel! Einen Überblick finden Sie in der MSDN Library zur Funktion MessageBox.

Unterstützte OS

Alle