AddElement()

Syntax

AddElement(LinkedList())

Fügt ein neues, leeres Listenelement nach dem aktuellen Element ein oder als erstes Element, wenn die Liste noch keine Elemente enthält. Dieses neue Element wird zum aktuellen Element der Liste.

Parameter:
LinkedList() - Der Variablenname der verknüpften Liste, welche mit dem NewList Befehl erstellt wurde. Sie müssen die Klammern nach dem Listennamen immer angeben.

Rückgabewert:
Der von diesem Befehl zurückgegebene Wert zeigt an, ob das neue Element hinzugefügt werden konnte oder nicht (es wird z.B. nicht erstellt, wenn Ihr Computer nicht mehr genügend freien Speicher hat). Wenn das neue Element erstellt wurde, gibt dieser Befehl einen Wert ungleich Null zurück. Konnte das neue Element nicht erstellt werden, ist der Rückgabewert gleich Null.

Nur für fortgeschrittene Anwender:
Der Wert, den dieser Befehl zurückgibt, ist ein Zeiger auf die Daten des neuen Elements, oder Null wenn das neue Element nicht erstellt werden konnte.

Beispiel:

  ; Der einfachste Weg zur Benutzung von AddElement
  NewList simple.w() 
  AddElement(simple())    ; Erstellt das erste neue Element innerhalb der Liste
  simple() = 23 
    
  AddElement(simple())    ; Aktuelle Position ist das erste Element, wir fügen
  simple() = 45           ; daher ein neues an der zweiten Position ein


  ; Das nachfolgende Beispiel zeigt die Benutzung des Rückgabewerts von AddElement
  NewList advanced.l() 
  If AddElement(advanced()) <> 0 
    advanced() = 12345 
  Else 
    MessageRequester("Fehler!", "Kein Speicherplatz zum Reservieren des neuen Elements", #PB_MessageRequester_OK)
  EndIf 


  ; Eine kleine Struktur, um die Beschreibung für "fortgeschrittene Anwender" (siehe oben) zu demonstrieren
  Structure Programmer
    Name.s
    Strength.b
  EndStructure

  NewList Programmers.Programmer()  ; The list for storing the elements

  *Element.Programmer = AddElement(Programmers())
  If *Element<>0
    *Element\Name = "Dave"
    *Element\Strength = 3   ; Wow, super-strong geek! ;)
  Else
    MessageRequester("Fehler!", "Kein Speicherplatz zum Reservieren des neuen Elements", #PB_MessageRequester_OK)
  EndIf 

Unterstützte OS

Alle