BeginVectorLayer()

Syntax

BeginVectorLayer([Alpha])

Beginnt einen neuen leeren Layer (Schicht) oberhalb der aktuellen Vektorzeichnen-Ausgabe. Alle nachfolgenden Zeichenoperationen werden auf diesem Layer ausgeführt, bis EndVectorLayer() aufgerufen wird. Dieser Befehl speichert auf die gleiche Weise wie SaveVectorState() auch den aktuelen Zeichenstatus. Es können mehrere Layer erstellt werden.

Parameter

Alpha (optional)

Definiert die Alpha-Transparenz des neuen Vektor-Layers. Erlaubte Werte reichen von 0 (vollständig transparent) bis 255 (völlig undurchsichtig). Der Standard ist 255 (völlig undurchsichtig).

Rückgabewert

Diese Funktion gibt keinen Wert zurück.

Anmerkungen

Die zum Erstellen des temporären Layers benötigten Ressourcen hängen von der Größe des aktuellen Clipping-Pfads ab. Um Ressourcen zu sparen und die Zeichen-Performance zu erhöhen, ist es daher empfehlenswert, einen Clipping-Pfad festzulegen, der nur den Bereich abdeckt, in welchem der temporäre Layer auch Zeichnungen beinhaltet.

Beispiel

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)

    If StartVectorDrawing(CanvasVectorOutput(0))

      ; Halb-transparentes Zeichnen auf dem Basis-Layer
      AddPathCircle(75, 100, 60)      
      VectorSourceColor(RGBA(255, 0, 0, 127))
      FillPath()      
      AddPathCircle(125, 100, 60)
      VectorSourceColor(RGBA(0, 0, 255, 127))
      FillPath()    
      
      ; Undurchsichtiges Zeichnen auf einem halb-transparenten Layer
      BeginVectorLayer(127)
        AddPathCircle(275, 100, 60)    
        VectorSourceColor(RGBA(255, 0, 0, 255))
        FillPath()        
        AddPathCircle(325, 100, 60)
        VectorSourceColor(RGBA(0, 0, 255, 255))
        FillPath()    
      EndVectorLayer()
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

EndVectorLayer(), SaveVectorState()

Unterstützte OS

Alle