Einsteiger-Kapitel - Variablen und das Verarbeiten von Variablen

A ist ein Integer - aber beachten Sie bitte, dass Sie keine Variablen auf diesem Weg deklarieren können, wenn Sie die EnableExplicit Direktive verwenden. Außerhalb einer Prozedur wird A im Geltungsbereich des Hauptcodes ("Main scope") existieren, innerhalb einer Prozedur wird sie lokal werden.
  A = 0

B ist eine Long Integer, C ist eine Fließkommazahl, sie werden mit Null initialisiert.
  Define B.l, C.f

D und E sind ebenfalls Long Integer. Sie werden jedoch mit den angegebenen Werten initialisiert. Beachten Sie auch den verwendeten alternativen Syntax von Define.
  Define.l D = 10, E = 20

F ist ein String.
  Define.s F

Dies ist auch G$. Wenn Sie Strings allerdings auf diese Weise deklarieren, müssen Sie immer die $ Notation verwenden.
  G$ = "Hello, "
Dies wird nicht funktionieren (G wird eine neue Integer Variable und ein Compiler-Fehler tritt auf).
  G = "Goodbye, World!"

H ist ein Array von 20 Strings, die Indizierung von Arrays beginnt bei Null.
  Dim H.s(19)
Jetzt ist H ein Array von 25 Strings. Wenn das Array vergrößert wird, bleiben seine originalen Inhalte erhalten.
  ReDim H.s(24)

J wird als Global erscheinen, und nicht (nur) im Geltungsbereich des Hauptcodes ("Main scope"). Es wird in allen Prozeduren gültig sein, aber es ist möglicherweise der bessere Weg, innerhalb einer Prozedur das Shared Schlüsselwort auf eine Variable des Hauptbereichs anzuwenden, damit die Möglichkeit unbeabsichtigter Änderungen minimiert wird.
  Global.i J

K wird eine neue, leere, Liste von Strings im Hauptgeltungsbereich ("Main scope").
  NewList K.s()

M wird eine neue, leere, Map von Strings im Hauptgeltungsbereich ("Main scope").
  NewMap M.s()

Beachten Sie bitte, dass Sie jedoch nicht die alternative Syntax des Define Schlüsselworts mit NewList bzw. NewMap verwenden können. Sonst wird ein Compiler-Fehler daraus resultieren.

Innerhalb einer Prozedur:
  Procedure TestVariables()
    
    ; N und P werden lokal sein.
    Define.l N
    Protected.l P
    
    ; Q wird eine statische lokale Variable sein.
    Static.l Q
    
    ; Die Variable F und die String-Liste K aus dem Geltungsbereich des Hauptcodes werden in dieser Prozedur verfügbar sein.
    Shared F, K()
    
    ; Die globale Variable J des Hauptgeltungsbereich wird hier ebenfalls verfügbar sein.
    
  EndProcedure

Das Verwenden von Operatoren auf Variablen:
  ; Addiert zwei zu A.
  A + 2
  
  ; Bitweises Or mit 21 (aus A wird 23)
  A | 21
  
  ; Bitweises And mit 1 (aus A wird 1)
  A & 1
  
  ; Arithmetische Verschiebung nach links (aus A wird 2, d.h. 10 in binär).
  A << 1

String-Verkettung
  G$ + "World!"

Ein Element zur K Liste hinzufügen:
  AddElement(K())
  K() = "List element one"

Ein Element zur M Map hinzufügen:
  M("one") = "Map element one"

Einsteiger-Kapitel Navigation

< Vorheriges: Erste Schritte | Überblick | Nächstes: Konstanten >