AddGadgetColumn()

Syntax

AddGadgetColumn(#Gadget, Position, Titel$, Breite)

Fügt eine Spalte zum angegebenen Gadget hinzu.

Parameter

#Gadget	Das zu verwendende Gadget.
Position	Der Spaltenindex, wo der neue Eintrag eingefügt werden soll. Ein Spaltenindex beginnt bei 0, was die am weitesten links befindliche Spalte bezeichnet, jede weitere Spalte nach rechts hat einen um 1 höheren Index. Wenn Sie eine Spalte hinzufügen, erhalten alle bisherigen Spalten rechts von der neuen Spalte einen um eins höheren Spaltenindex als sie vorher hatten.
Titel$	Der Text für die Spalten-Überschrift.
Breite	Die anfängliche Breite der neuen Spalte.

Rückgabewert

Diese Funktion gibt keinen Wert zurück.

Anmerkungen

Dieser Befehl kann mit den folgenden Gadget-Typen verwendet werden:

- ListIconGadget()
- ExplorerListGadget()

Beim ExplorerListGadget() können Sie diese Funktion benutzen, um vollständig die vom Gadget angezeigten Informationen anzupassen, indem Sie zuerst die Standardspalten mittels RemoveGadgetColumn() entfernen und dann neue Ihrer Wahl hinzufügen. Beachten Sie, dass die Spalte 'Name' nicht die erste im Gadget sein muss.
Hinweis: Um die Gadget-Inhalte nach dem Hinzufügen neuer Spalten zu aktualisieren, benutzen Sie SetGadgetText(). Um eine selbsterstellte ("custom") Spalte zu füllen, verwenden Sie SetGadgetItemText() für jeden Eintrag, nachdem Sie ein #PB_EventType_Change Ereignis für das Gadget empfangen haben.

Beim Hinzufügen einer Spalte benutzen Sie eine der folgenden Konstanten im 'Titel$' Feld, um eine Spalte zu erstellen, deren Inhalt durch das Gadget automatisch aktualisiert wird. Oder verwenden Sie einen selbst ausgewählten Text als Titel-String, wenn Sie eine leere Spalte erstellen möchten, welche Sie dann mit SetGadgetItemText() füllen können.

  #PB_Explorer_Name       : zeigt den Namen der Datei/des Verzeichnisses an
  #PB_Explorer_Size       : zeigt die Dateigröße in KB an
  #PB_Explorer_Type       : zeigt einen String an, der den Dateityp beschreibt
  #PB_Explorer_Attributes : zeigt die Attribute der Datei/des Verzeichnisses an
  #PB_Explorer_Created    : zeigt die Zeit an, zu der die Datei/das Verzeichnis erstellt wurde
  #PB_Explorer_Modified   : zeigt die Zeit an, zu der die Datei/das Verzeichnis zuletzt geändert wurde
  #PB_Explorer_Accessed   : zeigt die Zeit an, zu der zuletzt auf die Datei/das Verzeichnis zugegriffen wurde

Beispiel

  If OpenWindow(0, 0, 0, 400, 150, "ListIcon - Spalten hinzufügen", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ListIconGadget(0, 10, 10, 380, 100, "Standard-Spalte", 150, #PB_ListIcon_GridLines)
    ButtonGadget(1, 10, 120, 150, 20, "Neue Spalte hinzufügen")
    index = 1     ; "Standard-Spalte" hat bereits den Index 0
    Repeat
      Event = WaitWindowEvent()
      If Event = #PB_Event_Gadget
        If EventGadget() = 1
          AddGadgetColumn(0, index, "Spalte "+Str(index), 80)
          index + 1
        EndIf
      EndIf
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

RemoveGadgetColumn(), ListIconGadget(), ExplorerListGadget()

Unterstützte OS

Alle